require conf/distro/poky.conf
require conf/distro/include/arm-defaults.inc

DISTRO = "tdx-base"
DISTRO_NAME = "Toradex Distro Base"

TDX_BUILDNBR ?= "0"
TDX_PURPOSE ?= "Testing"

def get_tdx_prerelease(purpose, datetime):
    if purpose == "Testing":
        return '-devel-%s' % (datetime)
    elif purpose == "Nightly":
        return '-devel-%s' % (datetime[:8])
    elif purpose == "Monthly":
        return '-devel-%s' % (datetime[:6])
    elif purpose == "Release":
        return ''
    else:
        return '-devel-%s' % (datetime)

TDX_BUILD ?= "+build.${TDX_BUILDNBR}"
TDX_MATRIX_BUILD_TIME ?= "${DATETIME}"
TDX_MATRIX_BUILD_TIME[vardepsexclude] = "DATETIME"
TDX_PRERELEASE ?= "${@get_tdx_prerelease(d.getVar('TDX_PURPOSE'), d.getVar('TDX_MATRIX_BUILD_TIME'))}"
TDX_MAJOR ?= "0"
TDX_MINOR ?= "0"
TDX_PATCH ?= "0"
TDX_RELEASE ?= "${TDX_MAJOR}.${TDX_MINOR}.${TDX_PATCH}"

# Toradex Version number without date for U-Boot/Kernel and other Toradex
# specific software artifacts.
TDX_VERSION ?= "${TDX_RELEASE}${@'' if d.getVar('TDX_PURPOSE') == 'Release' else '-devel'}"

# Complete image version with date and build number
DISTRO_VERSION = "${TDX_RELEASE}${TDX_PRERELEASE}${TDX_BUILD}"

SDK_VENDOR = "-tdxsdk"
SDK_NAME_PREFIX = "${DISTRO}"
# do not use elements in SDK_VERSION which are in vardepsexclude
SDK_VERSION = "${TDX_RELEASE}"

MAINTAINER = "Toradex <yocto-patches@toradex.com>"

TARGET_VENDOR = "-tdx"

DISTROOVERRIDES .= ":tdx"

# create etc/build in the rootfs
INHERIT += "image-buildinfo"

# Log information on images and packages
INHERIT += "buildhistory"
BUILDHISTORY_COMMIT = "1"

# Use bluez5 as default.
DISTRO_FEATURES:append = " bluez5"

IMAGE_LINGUAS ?= "en-us"

# Some Toradex recipes like linux-toradex, u-boot-toradex,
# device-tree-overlays are appending SCM hashes to PV, version
# numbers going backwards are not a problem as we don't provide
# binary feeds.
#
# This avoids some annoying errors as follows:
# | QA Issue: Package version went backwards which would break package feeds
ERROR_QA:remove = "version-going-backwards"

# TODO: review default distro features
DISTRO_FEATURES:append = " pam systemd"
DISTRO_FEATURES:remove = "sysvinit ptest"
VIRTUAL-RUNTIME_init_manager = "systemd"
PACKAGECONFIG:append:pn-qemu-native = " libusb"

PREFERRED_PROVIDER_u-boot-fw-utils = "libubootenv"
PREFERRED_RPROVIDER_u-boot-fw-utils = "libubootenv"
PREFERRED_RPROVIDER_u-boot-default-env = "${PREFERRED_PROVIDER_virtual/bootloader}"

PREFERRED_PROVIDER_virtual/dtb ?= "device-tree-overlays"

# Use i.MX Gstreamer Version (for PXP DMA-ENGINE Driver)
PREFERRED_VERSION_gstreamer1.0:imx ?= "1.16.2.imx"
PREFERRED_VERSION_gstreamer1.0-plugins-base:imx ?= "1.16.2.imx"
PREFERRED_VERSION_gstreamer1.0-plugins-good:imx ?= "1.16.3.imx"
PREFERRED_VERSION_gstreamer1.0-plugins-bad:imx ?= "1.16.3.imx"

# the 1.16.imx variants have their COMPATIBLE set so that they don't build
# for use-mainline-bsp
PREFERRED_VERSION_gstreamer1.0:use-mainline-bsp ?= "1.18%"
PREFERRED_VERSION_gstreamer1.0-plugins-base:use-mainline-bsp ?= "1.18%"
PREFERRED_VERSION_gstreamer1.0-plugins-good:use-mainline-bsp ?= "1.18%"
PREFERRED_VERSION_gstreamer1.0-plugins-bad:use-mainline-bsp ?= "1.18%"

# Override Wayland/Weston Version set in meta-freescale imx-base.inc
PREFERRED_VERSION_wayland-protocols:mx6 = "1.20.imx"
PREFERRED_VERSION_wayland-protocols:mx7 = "1.20.imx"
PREFERRED_VERSION_wayland-protocols:mx8 = "1.20.imx"

PREFERRED_VERSION_weston:mx6 ?= "9.0.0.imx"
PREFERRED_VERSION_weston:mx7 ?= "9.0.0.imx"
PREFERRED_VERSION_weston:mx8 ?= "9.0.0.imx"

# Use i.MX libdrm Version
PREFERRED_VERSION_libdrm:mx6 = "2.4.102.imx"
PREFERRED_VERSION_libdrm:mx7 = "2.4.102.imx"
PREFERRED_VERSION_libdrm:mx8 = "2.4.102.imx"

PREFERRED_PROVIDER_opencl-headers:imxgpu      = "imx-gpu-viv"
PREFERRED_PROVIDER_opencl-clhpp:imxgpu        = "imx-gpu-viv"
PREFERRED_PROVIDER_opencl-icd-loader:imxgpu   = "imx-gpu-viv"
PREFERRED_RPROVIDER_opencl-icd-loader:imxgpu  = "libopencl-imx"