1 files changed, 40 insertions, 0 deletions
diff --git a/recipes-kernel/backports/backports_4.19.bb b/recipes-kernel/backports/backports_4.19.bb
new file mode 100644
index 0000000..43b77af
--- /dev/null
+++ b/recipes-kernel/backports/backports_4.19.bb
@@ -0,0 +1,40 @@
+SUMMARY = "Backported kernel drivers"
+HOMEPAGE = "https://backports.wiki.kernel.org"
+SECTION = "kernel/modules"
+LICENSE = "GPLv2"
+LIC_FILES_CHKSUM = "file://COPYING;md5=bbea815ee2795b2f4230826c0c6b8814"
+INC_PR = "r1"
+
+DEPENDS_append = " coreutils-native"
+
+SRCREV = "348fa3f6871f56a37dcd16c99ca98118c6d79a38"
+SRCREV_use-head-next = "${AUTOREV}"
+SRC_URI = " \
+    git://git.toradex.com/backports-toradex.git;protocol=git;branch=toradex-${PV} \
+    file://makefile.patch \
+    file://config \
+    "
+
+S = "${WORKDIR}/git"
+
+inherit module
+
+MAKE_TARGETS = "modules"
+MODULES_INSTALL_TARGET = "modules_install"
+PACKAGES_DYNAMIC += "^${BPN}-kernel-module-.*"
+
+KERNEL_MODULE_PACKAGE_PREFIX = "${BPN}-"
+
+EXTRA_OEMAKE = " KLIB=${STAGING_KERNEL_DIR} KLIB_BUILD=${STAGING_KERNEL_BUILDDIR} "
+
+do_configure() {
+
+    unset CFLAGS CPPFLAGS CXXFLAGS LDFLAGS
+    make CC="${BUILD_CC}" LD="${BUILD_LD}" AR="${BUILD_AR}" \
+         -C ${S}/kconf  O=${S}/kconf conf
+
+    cp ${WORKDIR}/config ${S}/.config
+    unset CFLAGS CPPFLAGS CXXFLAGS LDFLAGS
+    oe_runmake oldconfig
+}
+